2.18. Wat is het gemiddeld aantal ingezette FTE personeel niet in loondienst (PNIL) met een zorgfunctie?

Concepten

• Gewerkte periode
• Inhuurovereenkomst
• Uitzendovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.18
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12	?Periode
13	("Totaal organisatie" AS ?Indeling)
14	(FLOOR(COALESCE(SUM(?inzet_fte)/COUNT(?maand), 0)) AS ?Aantal_FTE)
15
16{
17    SELECT 
18    	?Periode 
19        ?maand
20        (SUM(?inzet_uren)/141 AS ?inzet_fte)
21    {
22        #BIND(2024 AS ?jaar)
23        VALUES ?kw { 1 2 3 4 0 }
24
25        BIND(xsd:date(CONCAT(STR(?jaar), "-",
26             IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
27        )) AS ?start_periode)
28
29        BIND(xsd:date(CONCAT(STR(?jaar), "-",
30             IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
31        )) AS ?eind_periode)
32
33        BIND(IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode)
34
35        VALUES ?type_overeenkomst 
36        { 
37            onz-pers:InhuurOvereenkomst
38            onz-pers:UitzendOvereenkomst
39        }
40        ?overeenkomst 
41            a ?type_overeenkomst ; # personeel niet in loondienst
42            onz-pers:heeftOpdrachtnemer ?persoon ;
43            onz-g:hasPart ?overeenkomst_afspraak .
44        ?overeenkomst_afspraak
45            a onz-pers:WerkOvereenkomstAfspraak ;
46            onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
47            onz-g:startDatum ?start_afspraak .
48        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
49        FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
50
51        ?inzet
52            a onz-pers:GewerktePeriode ;
53            onz-g:definedBy ?overeenkomst ;
54            onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
55            onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
56        BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
57        FILTER(?start_inzet >= ?start_periode && ?start_inzet <= ?eind_periode)
58        FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
59        BIND(MONTH(?start_inzet) AS ?maand)
60    }
61    GROUP BY ?Periode ?maand
62}
63GROUP BY ?Periode